Private Sub GetConstitPhones()
    Dim oRec As CRecord
    Dim oPhonesParent As IBBPhonesParent
    Dim oPhones As CConstitPhones
    Dim oPhone As IBBPhone
    
    Set oRec = New CRecord
    With oRec
        .Init REApplication.SessionContext
        .Load 203
              
        Set oPhonesParent = oRec
        oPhonesParent.IncludeOptions = ConstitPhoneOwner_Default
        Set oPhones = oPhonesParent.Phones
        
        For Each oPhone In oPhones
            Debug.Print oPhone.Fields(Phone_fld_Num)
            Debug.Print oPhone.Fields(Phone_fld_PhoneType)
            Debug.Print oPhone.Fields(Phone_fld_Indicator)
        Next oPhone
        
        Set oPhonesParent = Nothing
        Set oPhone = Nothing
        Set oPhones = Nothing
        
        .Closedown
    End With
    Set oRec = Nothing
    
End Sub


If you want the other phones, these are stored on the relationship.  You’ll need to do similar code, only against the cOrganization2 object:

Private Sub GetOrgRelanPhones()
    
    Dim oRec As CRecord
    Dim OrgReln As COrganization2
    Dim OrgRelns As COrganizations2
    Dim oPhonesParent As IBBPhonesParent
    Dim oPhones As CConstitPhones
    Dim oPhone As IBBPhone
    
    Set oRec = New CRecord
    With oRec
        .Init REApplication.SessionContext
        .Load 203
        
        Set OrgRelns = New COrganizations2
        OrgRelns.Init REApplication.SessionContext, oRec.Fields(RECORDS_fld_ID), tvf_Org2_PrimaryBusiness
        For Each OrgReln In OrgRelns
            ''Ought to only be one
                
            Set oPhonesParent = OrgReln
            oPhonesParent.IncludeOptions = ConstitPhoneOwner_Default
            Set oPhones = oPhonesParent.Phones     
            
            For Each oPhone In oPhones
                Debug.Print "Parent: " & oPhone.Fields(Phone_fld_Num)
                Debug.Print "Phone Type: " & oPhone.Fields(Phone_fld_PhoneType)
                Debug.Print "Phone Indicator: " & oPhone.Fields(Phone_fld_Indicator)
                Debug.Print "Parent ID: " & oPhone.Fields(Phone_fld_ParentId)
                Debug.Print "Import ID: " & oPhone.Fields(Phone_fld_Import_Id)
                Debug.Print ""
            Next oPhone
            
            Set oPhonesParent = Nothing
            Set oPhone = Nothing
            Set oPhones = Nothing
                            
            OrgReln.Closedown
        Next OrgReln
        Set OrgReln = Nothing
        
        OrgRelns.Closedown
        Set OrgRelns = Nothing
        
        .Closedown
    End With
    Set oRec = Nothing
End Sub


Disclaimer: We provide programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes you are familiar with Microsoft Visual Basic and the tools used to create and debug procedures. Our Customer Support can help explain the functionality of a particular procedure, but we will not modify, or assist you with modifying, these examples to provide additional functionality. If you are interested in learning more about the VBA and API modules, contact your account manager.